# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Simon Lipp <sloonz+aur@gmail.com>
# Paulo Matias

pkgname=scilab
pkgver=5.4.0
pkgrel=1
pkgdesc='A scientific software package for numerical computations.'
arch=('i686' 'x86_64')
url='http://www.scilab.org/'
license=('custom:CeCILL')
depends=('libxml2' 'pcre' 'lapack' 'fftw' 'bash' 'tk' 'hdf5' 'java-environment' 'arpack' 'shared-mime-info')
makedepends=('apache-ant' 'antlr2')
[[ $CARCH == x86_64 ]] && \
  source=("http://www.scilab.org/download/$pkgver/prerequirements-scilab-$pkgver-x86_64-src.tar.gz" 
  "http://www.scilab.org/download/${pkgver}/${pkgname}-${pkgver}-src.tar.gz" 'scilab.desktop')

[[ $CARCH == i686 ]] && \
  source=("http://www.scilab.org/download/${pkgver}/${pkgname}-${pkgver}-src.tar.gz" \
  "http://www.scilab.org/download/$pkgver/prerequirements-scilab-${pkgver}-src.tar.gz" \
  'scilab.desktop' 'classpath.xml')
[[ $CARCH == x86_64 ]] && md5sums=('4fd32852de92bfd79462927bb56f55be'
         '914b96d9b6534166539e7fea46bfd7f1'
         '460800803b34bfeb826b9b37d8c8fdd6')
[[ $CARCH == i686 ]] && md5sums=('0002653e670efabb8faf9e6403367134'
         '20688e191a77c904fdee08afa27b63b1'
         '460800803b34bfeb826b9b37d8c8fdd6')

install=$pkgname.install
options=('!libtool' '!emptydirs')

build() {
  LDFLAGS=${LDFLAGS/ -Wl,--as-needed}
  cd $srcdir/$pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --enable-build-localization \
    --without-matio \
    --without-umfpack \
    --with-fftw \
    --with-gfortran  # Needed for 64 bits, don't hurt for 32 bits

  make all doc
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install install-html

  install -d ${pkgdir}/usr/share/licenses/${pkgname}
  install -Dm644 ${srcdir}/scilab-${pkgver}/COPYING \
	${pkgdir}/usr/share/licenses/${pkgname}
  install -Dm644 ${srcdir}/${pkgname}.desktop \
	${pkgdir}/usr/share/applications/${pkgname}.desktop
  sed -i 's#/jni##' ${pkgdir}/usr/share/scilab/etc/librarypath.xml
}