# $Id$
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=moc
pkgver=2.5.2
pkgrel=1
epoch=1
pkgdesc="An ncurses console audio player designed to be powerful and easy to use"
arch=('i686' 'x86_64')
url="http://moc.daper.net/"
license=('GPL')
depends=('libmad' 'libid3tag' 'jack' 'curl' 'libltdl' 'file')
makedepends=('speex' 'ffmpeg' 'taglib' 'libmpcdec' 'wavpack' 'libmodplug' 'faad2')
optdepends=('speex: for using the speex plugin'
            'ffmpeg: for using the ffmpeg plugin'
            'taglib: for using the musepack plugin'
            'libmpcdec: for using the musepack plugin'
            'wavpack: for using the wavpack plugin'
            'faad2: for using the aac plugin'
            'libmodplug: for using the modplug plugin')
source=(http://ftp.daper.net/pub/soft/moc/stable/${pkgname}-${pkgver}.tar.bz2
        replaygain.patch::http://pastebin.com/raw/qXBB2n3R)
sha1sums=('9d27a929b63099416263471c16367997c0ae6dba'
          'fd17f3bbd10435a407ed4b4fdde5eecdb97461b7')

prepare() {
  cd ${pkgname}-${pkgver}
  patch -Np1 -i ${srcdir}/replaygain.patch
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr --without-rcc \
    --with-oss --with-alsa --with-jack --with-aac --with-mp3 \
    --with-musepack --with-vorbis --with-flac --with-wavpack \
    --with-sndfile --with-modplug --with-ffmpeg --with-speex \
    --with-samplerate --with-curl  --disable-cache --disable-debug
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}