# Based on community/sndio
# Reference: PKGBUILD(5)

pkgname='sndio1.2'
pkgver=1.2.0
pkgrel=1
pkgdesc='A small audio and MIDI framework part of the OpenBSD project'
arch=(x86_64)
url='http://www.sndio.org'
license=(ISC)
provides=('sndio')
conflicts=('sndio')

# sndio can be built without libbsd, but there are a bunch of individual
# ISC-licensed files by different authors to extract the licenses from
# if done that way. Licenses are complicated.
depends=(alsa-lib libbsd)

source=("http://www.sndio.org/sndio-$pkgver.tar.gz")
# checksums provided by packager
sha256sums=('b9808e189481904a4404b0c1715ad0c4b301e72abca8e49653bb526ff4e16cdc')
backup=(etc/default/sndiod)

build() {
	cd "sndio-$pkgver"
	./configure --prefix=/usr --enable-alsa --with-libbsd
	make
}

package() {
	cd "sndio-$pkgver"

	make DESTDIR="$pkgdir/" install

#	install -D -m 644 contrib/sndiod.service \
#		"$pkgdir/usr/lib/systemd/system/sndiod.service"
	install -D -m 644 contrib/default.sndiod \
		"$pkgdir/etc/default/sndiod"

	install -d "$pkgdir/usr/share/licenses/sndio"
	# this is the most up-to-date license outside of bsd-compat,
	# which isn't being used in this build
	sed '/^ \*\//q' aucat/aucat.c > "$pkgdir/usr/share/licenses/sndio/LICENSE"
}